2 Экспорт в файл
Для экспорта данных испльзуется метод:
recordset.Save Destination, PersistFormat
Destination – имя файла или объект типа Stream.
PersistFormat – формат вывода.

Параметр PersistFormat в нашем случае всегда будет равен adPersistXML. Параметр Destination открывает простор для творчесва, подробнее в примерах. Рассмотрим пример:

Public Function SaveRstToXml(ByRef rst As ADODB.Recordset _
                                 , ByVal stFileName As String)
'-- сохранить xml файл в Recordset
	If Dir(stFileName) <> "" Then
		Kill stFileName
	End If

	rst.Save stFileName, adPersistXML
End Function

В метод Save мы передали путь с именем файла. Перед тем как сохранить файл необходимо убедиться, что похожего файла нет или удалить его (стр. 9). Иначе произойдет ошибка выполнения. В результате получим xml файл такой же структуры, как и при использовании средств MS Access.
В документации указанно, что данные сохраняются в кодировке UTF-8. И в загловке файла нет привычного для XML заголовка, похожего на:<?xml version="1.0" encoding ="windows-1251"?>. Чтобы сохранить данные любой в другой кодировке можно восользоваться объектом ADO.Stream.
Смотрим:

Public Function SaveRstToXml2(ByRef rst As ADODB.Recordset _
                                 , ByVal stFileName As String)
'-- сохранить xml файл в Recordset
	Dim sm As ADODB.Stream               

	Set sm = New ADODB.Stream
	sm.Charset = "KOI8-R"       '-- любимая кодировка
	rst.Save sm, adPersistXML	'-- сохраняем в поток               

	If Dir(stFileName) <> "" Then
		Kill stFileName
	End If               

	sm.SaveToFile stFileName	'-- сохраняем поток в файл
	sm.Close
End Function

Обратите внимение, что тут в метод Save передан объект Stream.

Функции SaveRstToXml и SaveRstToXml2 являются библиотечными. При рельном использовании в них необходимо добавить обработку ошибок. Я не стал этого делать, чтобы не увеличивать код. Для удобства использования написана специализированая функция:

Public Function EportTblToXml(ByVal imTblFrom As String _
                             , ByVal imFileTo As String)
'-- экспортировать таблицу в xml файл
	Dim rstData As ADODB.Recordset
	Dim cnn As ADODB.Connection               

	Set cnn = CurrentProject.Connection
	Set rstData = New ADODB.Recordset     

	rstData.Open "SELECT * FROM " & imTblFrom, cnn _
	                 , adOpenKeyset, adLockOptimistic
	Call SaveRstToXml(rstData, imFileTo)
	rstData.Close
End Function

Ее задача подготовить данные для библиотечной фукнции. Таблица открывается в текущей базе данных. При изменении требований, именно эту фукнцию можно спокойно менять, например, добавить соединение с базой или фильтр экспортируемых данных.

3 Импорт из файла
Для экспорта данных испльзуется метод:
recordset.Open
Source – источник: SQL запрос, имя файла, объект Stream и п.р.
ActiveConnection – соединение.
CursorType – тип курсора.
LockType – тип блокировки.
Options – дополнительные опции.

Имя файла указывается на месте первого праметра Source. Если опустить все остальные параметры, то в результате откроется последовательный набор в режиме только для чтения. Быстро — то что нужно для импорта. Если нужно редактировать, то придется поиграть с параметрами CursorType и LockType.

Рассмотрим пример:

Public Function LoadXmlToRst(ByVal stFileName As String) As ADODB.Recordset
'-- загрузить в Recordset из xml файла
	Dim rst As ADODB.Recordset
	Set rst = New ADODB.Recordset     

	rst.Open stFileName	'-- открыть файл
	Set LoadXmlToRst = rst
End Function

Как оказывается все просто. Для надежного использования не хватает проверки наличия файла или обработки ошибок.
Также рассмотрим пример при чтении из потока с изменением кодировки:

Public Function LoadXmlToRst2(ByVal stFileName As String) As ADODB.Recordset
'-- загрузить в Recordset из xml файла
	Dim sm As ADODB.Stream
	Dim rst As ADODB.Recordset               

	Set sm = New ADODB.Stream     

	sm.Charset = "KOI8-R"       '-- любимая кодировка
	sm.Open
	sm.LoadFromFile stFileName  '-- загружаем файл в поток     

	Set rst = New ADODB.Recordset
	rst.Open sm       			'-- загружаем Recordset из потока
	sm.Close
	Set LoadXmlToRst2 = rst
End Function

Как и с экспортом написана специализированая функция ImportXmlToTbl. После открытия импортируемого файла в виде объекта Recordset импорт только начинается. Теперь данные необходимо обработать и поместить в базу. В примере все просто – данные добавляются без обарботки, но перед добавлением таблицу небоходимо очистить. Это происходит перед вызовом этой фукции.
Пример:

Public Function ImportXmlToTbl(ByVal imFileFrom As String _
                             , ByVal imTblTo As String)
'-- импортировать xml файл в БД
	Dim rstData As ADODB.Recordset
	Dim rstTo As ADODB.Recordset
	Dim fld As ADODB.Field
	Dim cnn As ADODB.Connection       

	Set cnn = CurrentProject.Connection
	Set rstTo = New ADODB.Recordset
	rstTo.Open "SELECT * FROM " & imTblTo, cnn _
	                 , adOpenKeyset, adLockOptimistic
	Set rstData = LoadXmlToRst(imFileFrom)       '-- добавляем данные из xml в таблицу
	'-- тут может происходить обновление данных
	'-- или любая другая обработка
	Do While Not rstData.EOF
		rstTo.AddNew         

		For Each fld In rstData.Fields
			rstTo(fld.Name) = fld.Value
		Next fld         

		rstTo.Update
		rstData.MoveNext
	Loop     

	rstData.Close
	rstTo.Update
	rstTo.Close
End Function

4 Итог
Данный метод хорошо тем, что позволяет с минимальными усилиями экспортировать и импортировть таблицы максимально гибко. Не так много кода нужно будет написать, чтобы экспортировать данные из стороннего mdb файла.
Недостатки не очень серьезные: структуру результирующего файла определяет сама библиотека ADO; нет возможности экспортировать данные в иеррахическом ввиде.

Подробности в примере.

Продолжение следует. В нем рассмотрим свой генератор XML.

Использованная литература: встроенная справка.

(с) Скоков Сергей

Надеюсь всем известно, что такое XML. Если нет, то осведомляться сюда. В какой-то момент жизни может возникнуть необходимость обмена данными с другими приложениями. Есть уже много форматов данных и много решений. Например, данные можно передавать в непосредственно mdb или dbf, cvs и п.р. Каждый формат имеет свои ограничения. Выгружать данные для сайта в mdb можно, но возникнут сложности с его обработкой. Формат XML хорош тем, что он текстовый и может содержать иерархические данные. Т.е. разбор текста можно написать и самому, чего в большинстве случаев не требуется, и вместо нескольких файлов можно передать один. Рассмотрим способы работы с XML для начала стандартные.

2 Средства MS Access

В Access 2003 реализовано две функции ExportXML и ImportXML.

Функция ExportXML позволяет экспортировать различные объекты базы данных. Такие как таблицы, отчеты, формы и т.п. Также позволяет экспортировать таблицы в иерархическом виде. При этом умеет формировать файл схемы данных и представления.

Синтаксис функции следующий:

ExportXML(ObjectType, DataSource, DataTarget, SchemaTarget, PresentationTarget, ImageTarget, Encoding, OtherFlags, FilterCriteria, AdditionalData)

ObjectType – тип экспортируемого объекта,
DataSource – имя источника данных,
DataTarget – имя файла назначения,
SchemaTarget – имя файла схемы,
PresentationTarget – имя файла представления
ImageTarget – путь для экспорта изображений,
Encoding – кодировка (UTF-8, UTF-16),
OtherFlags – параметры определяющие поведение при экспорте (см. в справке),
FilterCriteria – фильтр,
AdditionalData – Определяет дополнительные таблицы для экспорта.

В AdditionalData и кроется весь секрет экспорта иерархических данных. Функция проста в обращении. Примеры (я опустил нюансы, их можно посмотреть в примере):

Объявления переменных, чтобы не повторятся:

    Dim objInfoSub As AdditionalData
    Dim objInfoSubSub As AdditionalData

Экспорт данных:

    Set objInfoSub = Application.CreateAdditionalData
    Set objInfoSubSub = objInfoSub.Add("tblSub")
    objInfoSubSub.Add "tblSubSub"
    ExportXML acExportTable, "tblMain", CM_GetDBPath() & "AccessFunc_Tbl.xml" _
			 , CM_GetDBPath() & "AccessFunc_TblShema.xml", CM_GetDBPath() & "AccessFunc_Tbl.xsl" _
			 , "Images", , acEmbedSchema, , objInfoSub

Экспорт формы:

Set objInfoSub = Application.CreateAdditionalData
Set objInfoSubSub = objInfoSub.Add("tblSub")
objInfoSubSub.Add "tblSubSub"
ExportXML acExportForm, "frmMain", CM_GetDBPath() & "AccessFunc_Frm.xml" _
		 , CM_GetDBPath() & "AccessFunc_FrmShema.xml", CM_GetDBPath() & "AccessFunc_Frm.xsl" _
		 , "Images", , acEmbedSchema, , objInfoSub

Экспорт отчета:

ExportXML acExportReport, "rptMain", CM_GetDBPath() & "AccessFunc_Rpt.xml" _
        , CM_GetDBPath() & "AccessFunc_RptShema.xml", CM_GetDBPath() & "AccessFunc_Rpt.xsl" _
        , "Images", , acEmbedSchema

CM_GetDBPath() – возвращает путь к текущей базе. Ее можно увидеть в исходниках.

Самый главный интерес представляет экспорт данных, остальные для меня имею смутное представление. Файлы в результате сохранятся в каталог с базой. А полученные файлы html будут работать в IE, насчет остальных браузеров уверенности нет. Чтобы выгрузить иерархию необходимо заполнить схему данных. Тоже маленький минус.

Функция импорта ImportXML еще проще:

ImportXML(DataSource, ImportOptions)

DataSource – Имя файла.
ImportOptions – Опции импорта: acAppendData – добавить данные в таблицы, acStructureAndData – создать новые структуры таблиц и добавить данные, acStructureOnly – создать только структуры таблиц.

Код импорта прост:

ImportXML CM_GetDBPath() & "AccessFunc_Tbl.xml", acAppendData

Спрашивается: «Куда это все будет импортировано?», «Что будет, если подобные таблицы уже существуют?».

Имена таблиц берутся из xml файла. В результате — не любой xml подойдет. В нашем случае это тот, который был выгружен ExportXML (или с MS SQL сервера). Чтобы с этим подробнее разобраться, нужно посмотреть структуру полученных в прошлый раз файлов. Ничего сложного там нет. XML файл содержит две секции: структуры данных и самих данных. Воссоздать по образцу и подобию при необходимости не составит особого труда.

Если таблица с таким именем уже существует то, при загрузке данных они добавятся. А при создании новой структуры создадутся с номером.

Еще один недостаток. Импорт производится в текущую базу. При разделении интерфейса и данных придется отдельно запускать MSAccess, открывать отдельно базу (или создавать временную) и импортировать. Например, так:

Dim apAccess As Access.Application
'--открываем приложение и базу
apAccess.ImportXML ...

Если слепой импорт не устраивает, то это единственный вариант. Без дополнительной обработки и программирования никак.

Подробности в примере.

Продолжение следует. В нем рассмотрим средства библиотеки ADO.

Использованная литература: встроенная справка.

(с) Скоков Сергей